/**************************************************************************************************
 * Program:		New Miracles for Black & White 2
 * Purpose:		Forest.txt contains all the scripts needed for a miracle which creates numerous trees
 * Author:		Bill
 * Version: 	0
 * Date: 		Feb 2 2020
**************************************************************************************************/
//-------------------------------------------Scripts-----------------------------------------------
define script NMsFrst_createSymbolicBubble(idx, xPos, yPos, zPos, t_idx)
define script NMsFrst_createMiracleInHand
define script NMsFrst_hideSymbolicBubble(m_idx)
define script NMsFrst_CastPour(pwr,idx)
define script NMsFrst_CastThrown(pwr,idx)
define script NMsFrst_deleteMiracleInHand(idx)
define script NMsFrst_calculateMana(m_idx,pwr)
define script NMsFrst_CreateTree(obj)
//------------------------------------------Constants----------------------------------------------
define NMsFRST_MAXACTIVE			= 20
//-------------------------------------------Globals-----------------------------------------------
global NMsFrst_Count 				= 0

global NMsFrst_Hand[NMsFRST_MAXACTIVE]
global NMsFrst_HandV1[NMsFRST_MAXACTIVE]
global NMsFrst_HandV2[NMsFRST_MAXACTIVE]
global NMsFrst_HandActive[NMsFRST_MAXACTIVE]

global NMsFrst_HandLock				= NMs_FALSE		//Lock variable for NMsFrst_createMiracleInHand
global NMsFrst_HandResult			= 0				//Result variable for NMsFrst_createMiracleInHand

global NMsFrst_Casting 				= NMs_FALSE
global NMsFrst_Pile 				= 0

//--------------------------------------------Code-------------------------------------------------
begin script NMsFrst_createSymbolicBubble(idx, xPos, yPos, zPos, t_idx)
	calIdx = idx * NMs_MIR2D
	visHeight = 0
start
	visHeight = yPos + land height at {xPos,zPos}
	NMs_Miracles[calIdx + NMs_MIRTOTEM] = t_idx
	//Symbol Creation
	NMs_Miracles[calIdx + NMs_MIRSYMBOL] = create with angle 0 and scale 0.25 SCRIPT_OBJECT_TYPE_FEATURE FEATURE_INFO_AZTC_SUNTEMPLE at {xPos,yPos,zPos}
	override mesh for NMs_Miracles[calIdx + NMs_MIRSYMBOL] with "..\models\m_tree_oak"
	SCRIPT_OBJECT_PROPERTY_TYPE_YPOS of NMs_Miracles[calIdx + NMs_MIRSYMBOL] = yPos
	
	//Bubble Creation
	NMs_Miracles[calIdx + NMs_MIROBJ1] = create visual effect VISUAL_MIRACLE_TORNODO_SEED at {xPos,visHeight,zPos}+{0,1,0} time -1	
	NMs_Miracles[calIdx + NMs_MIROBJ2] = create visual effect VISUAL_EFFECT_HAND at {xPos,visHeight,zPos}+{0,1,0} time -1	
	//Scaling and Colouring
	SCRIPT_OBJECT_PROPERTY_TYPE_SCALE of NMs_Miracles[calIdx + NMs_MIROBJ2] = 0.5
	set NMs_Miracles[calIdx + NMs_MIROBJ1] colour red 0 green 127 blue 14
	set NMs_Miracles[calIdx + NMs_MIROBJ2] colour red 188 green 75 blue 0
	
	//Interaction commands
	disable NMs_Miracles[calIdx + NMs_MIRSYMBOL] pickup
	disable NMs_Miracles[calIdx + NMs_MIRSYMBOL] set on fire
	disable NMs_Miracles[calIdx + NMs_MIRSYMBOL] moveable
	
	enable NMs_Miracles[calIdx + NMs_MIRSYMBOL] interactable
	enable NMs_Miracles[calIdx + NMs_MIRSYMBOL] cylindar override
	
	//Other initialization
	NMs_Miracles[calIdx + NMs_VISIBLE] = NMs_TRUE
	NMs_Miracles[calIdx + NMs_MIRTYPE] = NMs_FOREST
	
end script NMsFrst_createSymbolicBubble

//Create the miracle in the player's hand
begin script NMsFrst_createMiracleInHand
	idx = -1
	cnt = 0
start
	while((cnt < NMsFRST_MAXACTIVE) and (idx == -1))
		if(NMsFrst_HandActive[cnt] == NMs_FALSE)
			idx = cnt
		end if
		cnt++
	end while
	
	NMsFrst_HandResult = idx
	NMsFrst_HandActive[idx] = NMs_TRUE
	
	//Symbol Creation
	NMsFrst_Hand[idx] = create with angle 0 and scale 0.25 SCRIPT_OBJECT_TYPE_ROCK MOBILE_STATIC_INFO_SMALL_NORSE_ROCK at hand position
	override mesh for NMsFrst_Hand[idx] with "..\models\m_tree_oak"
	//Bubble Creation
	NMsFrst_HandV1[idx] = create visual effect VISUAL_MIRACLE_TORNADO_IN_HAND on NMsFrst_Hand[idx] time -1	
	NMsFrst_HandV2[idx] = create visual effect VISUAL_EFFECT_HAND on NMsFrst_Hand[idx] time -1	
	set NMsFrst_Hand[idx] in player 0 hand
	//Scaling and Colouring
	SCRIPT_OBJECT_PROPERTY_TYPE_SCALE of NMsFrst_HandV2[idx] = 0.5
	set NMsFrst_HandV1[idx] colour red 0 green 127 blue 14
	set NMsFrst_HandV2[idx] colour red 188 green 75 blue 0
	
end script NMsFrst_createMiracleInHand

//Deletes the miracle in the player's hand
begin script NMsFrst_deleteMiracleInHand(idx)

start
	NMsFrst_HandActive[idx] = NMs_FALSE
	delete NMsFrst_Hand[idx]
	stop visual effect NMsFrst_HandV1[idx]
	stop visual effect NMsFrst_HandV2[idx]
end script NMsFrst_deleteMiracleInHand

//Hides the symbolic representation from the totem
begin script NMsFrst_hideSymbolicBubble(m_idx)
	m_ele = m_idx
	vis1 = 0
start
	delete NMs_Miracles[m_ele + NMs_MIRSYMBOL] with fade
	stop visual effect NMs_Miracles[m_ele + NMs_MIROBJ1]
	stop visual effect NMs_Miracles[m_ele + NMs_MIROBJ2]
end script NMsFrst_hideSymbolicBubble

//Calculates the mana required for this miracle, depending on the power passed in
begin script NMsFrst_calculateMana(m_idx,pwr)
	m_ele = m_idx * NMs_MIR2D
	m_mana = 0
start
	m_mana = 1000 * (pwr * 0.85) //at 1 [850]
	if(m_mana < 850) //Minimum
		m_mana = 850
	end if
	NMs_Miracles[m_ele + NMs_MANA] = m_mana
end script NMsFrst_calculateMana

//Script for pouring the miracle, NMsFrst_Casting is set false upon completion of the cast
//	Either by the amount of wheat is reached or the cancel is hit
begin script NMsFrst_CastPour(pwr, idx)
	amt = 0
	v_Pour = 0
	t_Amount = 0
	currentAmt = 0
	t_PerTick = 0
	
	pos = 0
	p_dist = 3
	p_x1 = 0
	p_z1 = 0
	p_x2 = 0
	p_z2 = 0
	
	t_obj = 0
	typ = 0
	
	ti_Tmr = create timer for 0 seconds
start
	NMsFrst_Casting = NMs_TRUE
	if(NMsFrst_HandActive[idx] == NMs_TRUE)
		set NMsFrst_Hand[idx] in player 0 hand
		
		//Calculate
		t_Amount = 2 * pwr
		if(t_Amount < 2)
			t_Amount = 2
		end if
		t_PerTick = 1
		
		pos = marker at {NMsFrst_Hand[idx]}

		set ti_Tmr time to 0.3 seconds
		
		begin loop		
			set NMsFrst_Hand[idx] in player 0 hand
			if((get ti_Tmr time remaining == 0) and (bindable action BINDABLE_ACTION_TYPE_ACTION performed) and (get player 0 influence at hand position > 0.1))				
				if(p_dist > 30)
					p_dist = 30
				end if
				v_Pour = create visual effect VISUAL_EFFECT_SHIELD_IMPACT at {pos} time 1
			
				SCRIPT_OBJECT_PROPERTY_TYPE_SCALE of v_Pour = p_dist / 10
				SCRIPT_OBJECT_PROPERTY_TYPE_STRENGTH of v_Pour = 1
				set v_Pour colour red 0 green 127 blue 14
				
				amt += t_PerTick
				
				pos = marker at {NMsFrst_Hand[idx]}
				
				//Calculate spot
				p_x1 = SCRIPT_OBJECT_PROPERTY_TYPE_XPOS of pos + ((p_dist) / NMs_MATHTHING) * cos(number from 0 to 360)
				p_z1 = SCRIPT_OBJECT_PROPERTY_TYPE_ZPOS of pos + ((p_dist) / NMs_MATHTHING) * sin(number from 0 to 360)

				//Pick a type of tree
				typ = number from 0 to 10
				if((typ == 5) or (typ == 8) or (typ == 7) or (typ == 2) or (typ == 4))
					typ = 1
				end if
				t_obj = create with angle 0 and scale 0.01 SCRIPT_OBJECT_TYPE_TREE constant typ at {p_x1,p_z1}
				
				run background script NMsFrst_CreateTree(t_obj)
				
				p_dist += 2
				set ti_Tmr time to 0.3 seconds
			end if
			until ((amt >= t_Amount) or (bindable action BINDABLE_ACTION_TYPE_CANCEL_CURRENT_ACTION performed))
		end loop
		
		stop visual effect v_Pour
		run script NMsFrst_deleteMiracleInHand(idx)
	end if
	
	NMsFrst_Casting = NMs_FALSE
end script NMsFrst_CastPour

begin script NMsFrst_CreateTree(obj)
	sz = 1
	inc = 0.02
	vis = 0
start
	if(obj exists)
		while(inc < sz)
			SCRIPT_OBJECT_PROPERTY_TYPE_SCALE of obj = inc
			inc += 0.02
		end while
		SCRIPT_OBJECT_PROPERTY_TYPE_SCALE of obj = sz
	end if
end script NMsFrst_CreateTree

//Script for throwing the miracle, NMsFrst_Casting is set false upon completion of the cast
begin script NMsFrst_CastThrown(pwr, idx)
	t_Amount = 0
	currentAmt = 0
	ti_Tmr = create timer for 60 seconds
	effect_go = NMs_TRUE
	pos = 0	//Position of the miracle when it hits something
	obj = 0
	p_x = 0
	p_z = 0
	pr = 0	//Random amount of piles
	ar = 0	//Random angle value in position calculations
	dr = 0	//Random distance value in position calculations
	ps = 0	//Pile Object
	pa = 0	//Amount per pile
	cnt = 0
	v_ex = 0
	typ = 0
	t_obj = 0
start
	NMsFrst_Casting = NMs_TRUE
	if(NMsFrst_HandActive[idx] == NMs_TRUE)
		//Calculate
		t_Amount = 2 * pwr
		if(t_Amount < 2)
			t_Amount = 2
		end if
		//Enable physics tracking
		enable NMsFrst_Hand[idx] physics tracking
		
		//Wait until something happens, or the time limit is hit
		wait until ((NMsFrst_Hand[idx] hit) or (NMsFrst_Hand[idx] hit land) or (get ti_Tmr time remaining == 0) or (not NMsFrst_Hand[idx] is moving))
		
		//If the time limit is reached, then something has gone terribly wrong! Exit at once!
		if(get ti_Tmr time remaining == 0)
			effect_go = NMs_FALSE
		end if
		
		pos = marker at {NMsFrst_Hand[idx]}
		//Remove the miracle in hand representation
		run script NMsFrst_deleteMiracleInHand(idx)
		
		if(effect_go == NMs_TRUE)
			//Create effects
			v_ex = create visual effect VISUAL_EFFECT_SHIELD_IMPACT at {pos} time -1
			
			SCRIPT_OBJECT_PROPERTY_TYPE_SCALE of v_ex = 3
			SCRIPT_OBJECT_PROPERTY_TYPE_STRENGTH of v_ex = 3
			set v_ex colour red 0 green 127 blue 14
			
			//Calculate positions
			while(cnt < t_Amount)
				//Pick a type of tree
				typ = number from 0 to 10
				if((typ == 5) or (typ == 8) or (typ == 7) or (typ == 2) or (typ == 4))
					typ = 1
				end if
				t_obj = create with angle 0 and scale 1 SCRIPT_OBJECT_TYPE_TREE constant typ at {pos}
				
				run background script NMs_LaunchObject(t_obj)
				
				cnt++
			end while
		end if
	end if
	NMsFrst_Casting = NMs_FALSE
end script NMsFrst_CastThrown
