define script CreatureSelect
define script CreaturePen

begin script CreaturePen
	oPen = 0
	CreatureHomePos = 0
	oCreature = 0

start
	wait until get player 0 creature exists
	oCreature = get player 0 creature

	begin loop
		wait 10 seconds
		oPen = get building ABODE_NUMBER_CREATURE_PEN in playerTown min built 1.0
		if oPen exists
			CreatureHomePos = marker at {oPen}
		else
			CreatureHomePos = marker at {playerTown}+{0,0,20}
		end if
		set oCreature home position {CreatureHomePos}

		until oPen exists
	end loop
end script CreaturePen

begin script CreatureSelect
	aCreature = 0
	cCreature = 0
	lCreature = 0
	tCreature = 0
	wCreature = 0
	oCreature = 0
	sPos = 0
	Vis = 0
	Size = 7

start
	enable global influence
	wait until playerTown exists

	sPos = marker at {playerTown}+{0,0,30}

	wCreature = create SCRIPT_OBJECT_TYPE_CREATURE CREATURE_TYPE_WOLF at {sPos}+{-24,0} using only alignment good neutral evil
	set creature wCreature CREATURE_SCRIPT_TRANSITIONAL_ATTRIBUTE_TYPE_SIZE Size/10
	aCreature = create SCRIPT_OBJECT_TYPE_CREATURE CREATURE_TYPE_APE at {sPos}+{-12,0} using only alignment good neutral evil
	set creature aCreature CREATURE_SCRIPT_TRANSITIONAL_ATTRIBUTE_TYPE_SIZE Size/10
	lCreature = create SCRIPT_OBJECT_TYPE_CREATURE CREATURE_TYPE_LION at {sPos}+{0,0} using only alignment good neutral evil
	set creature lCreature CREATURE_SCRIPT_TRANSITIONAL_ATTRIBUTE_TYPE_SIZE Size/10
	tCreature = create SCRIPT_OBJECT_TYPE_CREATURE CREATURE_TYPE_TIGER at {sPos}+{12,0} using only alignment good neutral evil
	set creature tCreature CREATURE_SCRIPT_TRANSITIONAL_ATTRIBUTE_TYPE_SIZE Size/10
	cCreature = create SCRIPT_OBJECT_TYPE_CREATURE CREATURE_TYPE_COW at {sPos}+{24,0} using only alignment good neutral evil
	set creature cCreature CREATURE_SCRIPT_TRANSITIONAL_ATTRIBUTE_TYPE_SIZE Size/10

	disable toolbar
	disable load screen
	set fade in time 1

	begin cinema
		set camera focus to {sPos}
		wait 5 seconds
		move camera focus to {sPos}+{0,15,0} time 3
		wait until camera ready
		move camera position to {sPos}+{0,25,-40} time 5
		wait 2 seconds
		move camera focus to {sPos}+{0,15,0} time 2
		wait until camera ready
		stop music with fadetime 6

		make good spirit appear
		wait 1 seconds
		make good spirit point to lCreature
		say "BW2T_SCRIPT_01FINAL_ADVISORS_CHOOSE_CREATURENEW_10"
		wait 1 seconds
		stop good spirit pointing
		wait 3 seconds
		send good spirit home
		say "Change creature size by pressing the 1 or 2 keys"
		wait 3 seconds
	end cinema

	begin loop
		wait 0.2 seconds
		if key KB_1 down
			Size--
			if Size < 3
				Size = 3
			end if
		elsif key KB_2 down
			Size++
			if Size > 10
				Size = 10
			end if
		end if

		set creature wCreature CREATURE_SCRIPT_TRANSITIONAL_ATTRIBUTE_TYPE_SIZE Size/10
		set creature aCreature CREATURE_SCRIPT_TRANSITIONAL_ATTRIBUTE_TYPE_SIZE Size/10
		set creature lCreature CREATURE_SCRIPT_TRANSITIONAL_ATTRIBUTE_TYPE_SIZE Size/10
		set creature tCreature CREATURE_SCRIPT_TRANSITIONAL_ATTRIBUTE_TYPE_SIZE Size/10
		set creature cCreature CREATURE_SCRIPT_TRANSITIONAL_ATTRIBUTE_TYPE_SIZE Size/10

		if bindable action BINDABLE_ACTION_TYPE_ACTION performed
			wait 0.2 seconds
			if wCreature right clicked or wCreature left clicked
				Vis = create visual effect VISUAL_EFFECT_GOLD_SCROLL at {wCreature} time 2
				oCreature = wCreature
				delete aCreature
				delete lCreature
				delete tCreature
				delete cCreature	
			elsif aCreature right clicked or aCreature left clicked
				Vis = create visual effect VISUAL_EFFECT_GOLD_SCROLL at {aCreature} time 2
				oCreature = aCreature
				delete wCreature
				delete lCreature
				delete tCreature
				delete cCreature	
			elsif lCreature right clicked or lCreature left clicked
				Vis = create visual effect VISUAL_EFFECT_GOLD_SCROLL at {lCreature} time 2
				oCreature = lCreature
				delete wCreature
				delete aCreature
				delete tCreature
				delete cCreature	
			elsif tCreature right clicked or tCreature left clicked
				Vis = create visual effect VISUAL_EFFECT_GOLD_SCROLL at {tCreature} time 2
				oCreature = tCreature
				delete wCreature
				delete aCreature
				delete lCreature
				delete cCreature	
			elsif cCreature right clicked or cCreature left clicked
				Vis = create visual effect VISUAL_EFFECT_GOLD_SCROLL at {cCreature} time 2
				oCreature = cCreature
				delete wCreature
				delete aCreature
				delete lCreature
				delete tCreature
			else 
				empty player hand
				begin fullscreen cinema
					set camera focus to {sPos}+{0,15,0}
					set camera position to {sPos}+{0,25,-40}
				end cinema
				oCreature = 0
			end if
		end if
		until oCreature exists
	end loop

	set oCreature home position {sPos}
	set creature oCreature happiness to maximum
	set creature oCreature energy to 1.0
	set creature oCreature CREATURE_SCRIPT_TRANSITIONAL_ATTRIBUTE_TYPE_ALIGNMENT 0
	set player 0 creature to oCreature
	enable leash on oCreature
	detach oCreature leash
	
	begin cinema
		wait 1 seconds
		snap creature oCreature focus to camera position
		move camera focus to {oCreature} time 2
		wait 1 seconds	
		set fade in time 1
	end cinema
	
	enable toolbar
	set toolbar state to MENU_TOOLBAR_STATE_CLOSED
	enable global influence
	increment tribute by 500000
	
end script CreatureSelect

